//**************************************************
//*
//* Title: Free Script Sample
//* Make : 2006/09/15(Revision Fakefur)
//* Note : Put   -> Initialization
//*        Sit   -> Target Sit
//*
//**************************************************
vector SitXYZ = <0.0, 0.0, 1.0>;     //Sit X,Y,X Status
key User1ndID = NULL_KEY;            //1nd User ID
integer SitStatus = FALSE;           //"Sit" = TRUE : "Not Sit" = FALSE
string SitAnimeName = "Dance 14";    //Sit Anime FileName
string Mes = "Sit Sample(Dance)";

//****************
//* Main Program *
//****************
default
{
    //******************
    //* Initialization *
    //******************
    state_entry()
    {

        llSetText(Mes, <1,1,1>, 1.0);          //Message
        llSetSitText( "Pose" );                //Menu "Sit" -> "Pose"
        //****************
        //* Sit Position *
        //****************
        llSitTarget(SitXYZ,ZERO_ROTATION);     //Set Position And Rotation
    }

    //*******************************
    //* Sit And StandUp SelectEvent *
    //*******************************
    changed(integer change) 
    {
        if (change & CHANGED_LINK)
        {
            key agent = llAvatarOnSitTarget();  //Get "Sit Select User ID"
            //************
            //* Sit User *
            //************
            //"USER not Sit" And "SitSelect User Active"
            if ( User1ndID == NULL_KEY && agent != NULL_KEY ) 
            {
                //****************
                //* Sit Event ON *
                //****************
                User1ndID = agent;           //Set 1ndUserID(2nd User Lock)
                llRequestPermissions(User1ndID,PERMISSION_TRIGGER_ANIMATION);
            }
            //***********
            //* StandUp *
            //***********
            else if ( User1ndID != NULL_KEY && agent == NULL_KEY)
            {
                if (SitStatus == TRUE) 
                {
                    llStopAnimation(SitAnimeName); //StopAnimetion
                }
                llResetScript();                   //Script Reset
           }
        }
    }

    //*************
    //* Sit Event *
    //*************
    run_time_permissions(integer parm) 
    {
        if(parm == PERMISSION_TRIGGER_ANIMATION) 
        {
            SitStatus = TRUE;                      //1nd User Set Flag ON
            llStopAnimation("sit");                //Cancel Sit Animation
            llStartAnimation(SitAnimeName);        //Set UserSit Animation
        }
    }
}